С целью проверки справедливости распространенного в трейдерской среде утверждения «Обрезай убытки и позволяй прибыли расти» была разработана данная торговая система и написан советник.



Суть торговой системы в том, что по сигналу индикатора открываются сделки со стопом в направлении дневного тренда до тех пор пока не накапливаем необходимый профит в валюте. Одновременно может быть открыто не более 100 ордеров.

Советник оптимизировался по ценам открытия на паре EURUSD, ТФ Н1.

//+------------------------------------------------------------------+
//|                                                       BBands.mq4 |
//|                                              Copyright 2016, AM2 |
//|                                      http://www.forexsystems.biz |
//+------------------------------------------------------------------+
#property copyright "Copyright 2016, AM2"
#property link      "http://www.forexsystems.biz"
#property description "BBands expert advisor"

//--- Inputs
extern double Lots         = 0.1;  // лот
extern double Profit       = 3000; // язь в рублях
extern int    StopLoss     = 5000; // лось
extern int    TakeProfit   = 0;    // язь
extern int    Slip         = 30;   // реквот
extern int    Magic        = 20;   // магик

extern string s="------------- Настройки BBands  -------------";
extern int    Length       = 20;   // период BB 
extern double Deviation    = 2;    // отклонение ВВ
extern string ss="------------- Настройки MA  -------------";
extern int    PeriodMA     = 20;   // период MA

datetime t=0;
//+------------------------------------------------------------------+
//| Expert initialization function                                   |
//+------------------------------------------------------------------+
int OnInit()
  {
//---

//---
   return(INIT_SUCCEEDED);
  }
//+------------------------------------------------------------------+
//| Expert deinitialization function                                 |
//+------------------------------------------------------------------+
void OnDeinit(const int reason)
  {
//---

  }
//+------------------------------------------------------------------+
//| Check for open order conditions                                  |
//+------------------------------------------------------------------+
void PutOrder(int type,double price)
  {
   int r=0;
   color clr;
   double sl=0,tp=0;

   if(type==1 || type==3 || type==5)
     {
      clr=Red;
      if(StopLoss>0)   sl=NormalizeDouble(price+StopLoss*Point,Digits);
      if(TakeProfit>0) tp=NormalizeDouble(price-TakeProfit*Point,Digits);
     }

   if(type==0 || type==2 || type==4)
     {
      clr=Blue;
      if(StopLoss>0)   sl=NormalizeDouble(price-StopLoss*Point,Digits);
      if(TakeProfit>0) tp=NormalizeDouble(price+TakeProfit*Point,Digits);
     }

   r=OrderSend(NULL,type,Lots,NormalizeDouble(price,Digits),Slip,sl,tp,"",Magic,0,clr);
   return;
  }
//+------------------------------------------------------------------+
//|                                                                  |
//+------------------------------------------------------------------+
int CountTrades()
  {
   int count=0;
   for(int i=OrdersTotal()-1;i>=0;i--)
     {
      if(OrderSelect(i,SELECT_BY_POS,MODE_TRADES))
        {
         if(OrderSymbol()==Symbol() && OrderMagicNumber()==Magic)
           {
            if(OrderType()<2) count++;
           }
        }
     }
   return(count);
  }
//+------------------------------------------------------------------+
//|                                                                  |
//+------------------------------------------------------------------+
double AllProfit()
  {
   double profit=0;

   for(int i=OrdersTotal()-1;i>=0;i--)
     {
      if(OrderSelect(i,SELECT_BY_POS,MODE_TRADES))
        {
         if(OrderSymbol()==Symbol() && OrderMagicNumber()==Magic)
           {
            if(OrderType()<2) profit+=OrderProfit()+OrderSwap()+OrderCommission();
           }
        }
     }
   return (profit);
  }
//+------------------------------------------------------------------+
//| Check for open order conditions                                  |
//+------------------------------------------------------------------+
void OpenPos()
  {
//--- get Ind
   double up=iBands(NULL,0,Length,Deviation,0,0,1,1);
   double dn=iBands(NULL,0,Length,Deviation,0,0,2,1);
   double ma=iMA(NULL,PERIOD_D1,PeriodMA,0,0,0,1);

//--- sell conditions
   if(Close[2]>up && Close[1]<up && Bid<ma)
     {
      PutOrder(1,Bid);
     }
//--- buy conditions
   if(Close[2]<dn && Close[1]>dn && Ask>ma)
     {
      PutOrder(0,Ask);
     }
//---
  }
//+------------------------------------------------------------------+
//|                                                                  |
//+------------------------------------------------------------------+
void CloseAll()
  {
   bool c=true;

   for(int i=OrdersTotal()-1;i>=0;i--)
     {
      if(OrderSelect(i,SELECT_BY_POS,MODE_TRADES))
        {
         if(OrderSymbol()==Symbol() && OrderMagicNumber()==Magic)
           {
            if(OrderType()==OP_BUY) c=OrderClose(OrderTicket(),OrderLots(),Bid,Slip,Blue);
            if(OrderType()==OP_SELL) c=OrderClose(OrderTicket(),OrderLots(),Ask,Slip,Red);
           }
        }
     }
   return;
  }
//+------------------------------------------------------------------+
//| OnTick function                                                  |
//+------------------------------------------------------------------+
void OnTick()
  {
   if(t!=Time[0])
     {
      if(CountTrades()<100) OpenPos();
      if(AllProfit()>Profit) CloseAll();
      t=Time[0];
     }

   Comment("\n ");
  }
//+------------------------------------------------------------------+

После оптимизации ТС с начала 2000-го года я выбрал параметры с наименьшей просадкой и максимальной прибылью.



Система дала нам примерно 620% прибыли за 15 лет. Это 41% в год, при просадке 48% за всю историю.



График роста баланса приведен ниже.



Если тестировать на всех тиках, результат будет тот же.



П.С. Как показали результаты оптимизации и тестирования данной ТС, утвержение «Обрезай убытки и позволяй прибыли расти» является верным.
Система трендовая, если у вас есть инсайд что пара будет длительное время расти или снижаться можете смело ее использовать, конечно же учитывая все риски.

Скачать советник можно по ссылке: www.opentraders.ru/downloads/1028/